1. Окно выбора действия
В Delphi имеется функция MessageDlg, отображающая диалоговое окно
сообщений в центре экрана, и ожидает ответа пользователя.
function MessageDlg(const Msg: string; DlgType: TMsgDlgType; Buttons: TMsgDlgButtons; HelpCtx: Longint): Integer;
где:
Msg – текст сообщения;
DlgType – определяет внешний вид диалогового окна, значения
которых даны ниже:
mtWarning – тревожное оповещение (восклицательный знак в
желтом треугольнике),
mtError – оповещение об ошибке (крест в красном кругу),
mtInformation – информационное сообщение (символ "i" в
синем кругу),
mtConfirmation – запрос (зеленый знак вопроса),
mtCustom – сообщение без рисунка, заголовок окна содержит
название проекта,
Buttons – определяет, какие кнопки будут присутствовать в окне
(значения видов кнопок: mbYes, mbNo, mbOK,
mbCancel, mbAbort, mbRetry,
mbIgnore, mbAll, mbNoToAll,
mbYesToAll, mbHelp). Список необходимых кнопок заключается
в квадратные скобки [ ], поскольку параметр Buttons:
TMsgDlgButtons является множеством. Если внутри скобок список отсутствует,
в окне не будет ни одной кнопки и пользователю придется закрывать окно системными
кнопками Windows. Кроме множества значений, соответствующих отдельным кнопкам, в
Delphi определены несколько констант, соответствующие часто используемым сочетаниям
кнопок:
mbYesNoCancel – включает в окно кнопки Yes,
No и Cancel,
mbOKCancel – включает в окно кнопки OK и
Cancel,
mbAbortRetryIgnore – включает в окно кнопки
Abort, Retry и Ignore,
mbYesAllNoAllCancel – включает в окно кнопки
Yes, YesToAll, No, NoToAll
и Cancel,
mbAbortIgnore – включает в окно кнопки
Abort и Ignore,
HelpCtx – предназначен для взаимодействия со справкой
приложения, в нем задается индекс соответствующей диалоговому окну страницы
справки.
Например,
case MessageDlg('Какую кнопку Вы желаете нажать?', mtConfirmation, mbYesNoCancel, 0) of
mrYes: MessageDlg('Вы нажали на "YES"!', mtInformation, [mbOK], 0);
mrNo: MessageDlg('Вы нажали на "NO"!', mtWarning, [mbOK], 0);
else
MessageDlg('Вы либо закрыли окно, либо нажали на "Cancel"!', mtError, [], 0);
end;
Усовершенствуем эту функцию, написав собственную FormMessage, возвращающее
номер нажатой кнопки:
- 0 (
mrNone) – пользователь закрыл
окно, не нажав на кнопку;
- 1 (
mrOk) – пользователь нажал на
1-ю кнопку;
- 2 (
mrCancel) – пользователь
нажал на 2-ю кнопку;
- 3 (
mrAbort) – пользователь нажал
на 3-ю кнопку.
uses ExtCtrls, StdCtrls, MMSystem, Math; // если некоторые отсутствуют, допишите!
function FormMessage(Caption, SMS, Button1Caption, Button2Caption, Button3Caption: string; DlgType: TMsgDlgType): byte;
var Form: TForm;
l, t: integer;
begin
{****************************************}
{ Значения TModalResult (номера кнопок): }
{ mrNone = 0 }
{ mrOk = 1 }
{ mrCancel = 2 }
{ mrAbort = 3 }
{****************************************}
repeat
if Button1Caption='' then
begin
Button1Caption:=Button2Caption;
Button2Caption:=Button3Caption;
Button3Caption:='';
end;
if Button2Caption='' then
begin
Button2Caption:=Button3Caption;
Button3Caption:='';
end;
if (Button1Caption='') and (Button2Caption='') and (Button3Caption='')
then
Button1Caption:='OK';
until Button1Caption<>'';
Form:=TForm.CreateNew(Application);
Form.Font.Charset:=ANSI_CHARSET;
Form.BorderStyle:=bsDialog;
Form.Position:=poScreenCenter;
Form.Caption:=Caption;
if DlgType<>mtCustom then
with TImage.Create(Form) do
begin
Parent:=Form;
SetBounds(8, 8, 32, 32);
Transparent:=true;
case DlgType of
mtWarning: Picture.Icon.Handle:=LoadIcon(0, IDI_EXCLAMATION);
mtError: Picture.Icon.Handle:=LoadIcon(0, IDI_HAND);
mtInformation: Picture.Icon.Handle:=LoadIcon(0, IDI_ASTERISK);
mtConfirmation: Picture.Icon.Handle:=LoadIcon(0, IDI_QUESTION);
end;
end;
with TLabel.Create(Form) do
begin
Parent:=Form;
AutoSize:=false;
WordWrap:=true;
if DlgType=mtCustom then
Left:=8 else
Left:=48;
Top:=8;
Width:=600;
Caption:=SMS;
AutoSize:=true;
Form.ClientWidth:=MaxIntValue([256, Left+Width+8]);
t:=Top+Height+8;
if DlgType<>mtCustom then
t:=MaxIntValue([t, 48]);
end;
with TButton.Create(Form) do
begin
Parent:=Form;
Default:=true;
ModalResult:=mrOk;
Caption:=Button1Caption;
l:=(Form.ClientWidth-Width) div 2;
if Button2Caption<>'' then
l:=l-Width div 2-4;
if Button3Caption<>'' then
l:=l-Width div 2-4;
Left:=l;
l:=l+Width+8;
Top:=t;
t:=t+Height+8;
end;
if Button2Caption<>'' then
with TButton.Create(Form) do
begin
Parent:=Form;
ModalResult:=mrRetry;
Caption:=Button2Caption;
Left:=l;
l:=l+Width+8;
Top:=t-Height-8;
end;
if Button3Caption<>'' then
with TButton.Create(Form) do
begin
Parent:=Form;
ModalResult:=mrAbort;
Caption:=Button3Caption;
Left:=l;
Top:=t-Height-8;
end;
Form.ClientHeight:=t;
case DlgType of
mtWarning: PlaySound('SystemExclamation', 0, SND_ASYNC);
mtError: PlaySound('SystemHand', 0, SND_ASYNC);
mtInformation: PlaySound('SystemAsterisk', 0, SND_ASYNC);
mtConfirmation: PlaySound('SystemQuestion', 0, SND_ASYNC);
end;
Result:=Form.ShowModal;
{ При закрытии окна (на крестик) Result = mrCancel }
case Result of
mrCancel: Result:=mrNone;
mrRetry: Result:=mrCancel;
end;
FreeAndNil(Form);
end;
где:
Caption – заголовок диалогового окна;
SMS – текст сообщения;
Button1Caption, Button2Caption,
Button3Caption – названия кнопок;
DlgType – определяет внешний вид диалогового окна, значения
которых такие же, как и у функции MessageDlg (см. выше).
Например,
if FormMessage('Вопрос', 'Вы действительно хотите подтвердить свое действие?', 'Да', 'Нет', '', mtConfirmation)=mrOk then
begin
case FormMessage('Информация', 'Нажмите на кнопку', 'Выбор', 'Список', 'Значение', mtInformation) of
mrOk: FormMessage('Внимание', 'Вы нажали на кнопку "Выбор"', '', 'Да', 'Нет', mtWarning);
mrCancel: FormMessage('Внимание', 'Вы нажали на кнопку "Список"', '', '', 'OK', mtWarning);
mrAbort: FormMessage('Внимание', 'Вы нажали на кнопку "Значение"', 'Хорошо', '', 'Отмена', mtWarning);
else
FormMessage('Ошибка', 'Вы ничего не нажимали', 'Принять', '', '', mtError);
end;
end else
FormMessage('Сообщение', 'Программа работает без изменений!', '', '', '', mtCustom);
Примечание. Обратите внимание на строку
Result:=Form.ShowModal. Закрываясь, модальная форма возвращает
целочисленное значение, называемое модальным результатом. В модальном результате
кодируется решение пользователя, нажавшего ту или иную кнопку на форме. При закрытии
окна через системную кнопку "Крестик", находящуюся вверху справа,
ShowModal становится равным 2, что крайне
неудобно для второй кнопки. Поэтому в коде функции для 2-й кнопки устанавливается
свойство ModalResult, равным mrRetry
(4). А после закрытия окна результат функции
переопределяется (mrCancel → 0,
mrRetry → 2). Для проверки вывода
номера нажатой кнопки на пустую форму можно добавить кнопки Button1:
TButton и метку (надпись) Label1: TLabel и вызвать событие.
procedure TForm1.Button1Click(Sender: TObject);
begin
Label1.Caption:=IntToStr(FormMessage('Вопрос', 'Нажмите на кнопку', 'Да', 'Нет', 'Отмена', mtConfirmation));
Label1.Caption:=IntToStr(FormMessage('Информация', 'Нажмите на кнопку', 'OK', '', '', mtInformation));
Label1.Caption:=IntToStr(FormMessage('Внимание', 'Нажмите на кнопку', '', 'Да', 'Нет', mtWarning));
Label1.Caption:=IntToStr(FormMessage('Ошибка', 'Нажмите на кнопку', '', '', '', mtError));
Label1.Caption:=IntToStr(FormMessage('Сообщение', 'Нажмите на кнопку', 'Выбор', 'Список', 'Значение', mtCustom));
end;
2. Окно ввода данных
В Delphi имеются функции InputBox и InputQuery, отображающая
каждая из них свое диалоговое окно, содержащее строку ввода, и возвращают содержимое
текстовой строки.
function InputBox(const ACaption, APrompt, ADefault: string): string;
function InputQuery(const ACaption, APrompt: string; var Value: string): Boolean;
где:
ACaption – заголовок диалогового окна;
APrompt – надпись над строкой ввода (текст сообщения);
ADefault – значение по умолчанию;
Value – возвращает содержимое текстовой строки.
Например,
Caption := InputBox('Создание файла', 'Имя файла',
'Новый файл.txt'); при нажатии на кнопку "OK" в заголовке главного окна
выведет содержимое текстовой строки, введеное пользователем; а при нажатии на кнопку
"Cancel", либо при закрытии диалогового окна выведет 'Новый
файл.txt' независимо от содержимого текстовой строки;
procedure TForm1.Button1Click(Sender: TObject);
var Value: string;
begin
if InputQuery('Регистрация', 'Фамилия:', Value) then
Caption:=Value else
Caption:='Пользователь отказался вводить данные!';
end;
Если пользователь нажал кнопку "OK", то в заголовке главного окна выведет содержимое
текстовой строки; а при нажатии на кнопку "Cancel", либо при закрытии диалогового
окна выведет 'Пользователь отказался вводить
данные!'.
Усовершенствуем эту функцию, написав собственную FormInput, возвращающее
содержимое текстовой строки:
uses StdCtrls, Mask, Math; // если некоторые отсутствуют, допишите!
function FormInput(Caption: string; SMS, MEditText, MEditMask: string; MPasswordChar: char; var Value: string): boolean;
var Form: TForm;
MaskEdit: TMaskEdit;
t: integer;
begin
Form:=TForm.CreateNew(Application);
Form.Font.Charset:=ANSI_CHARSET;
Form.BorderStyle:=bsDialog;
Form.Position:=poScreenCenter;
Form.Caption:=Caption;
with TLabel.Create(Form) do
begin
Parent:=Form;
AutoSize:=false;
WordWrap:=true;
Left:=8;
Top:=8;
Width:=600;
Caption:=SMS;
AutoSize:=true;
Form.ClientWidth:=MaxIntValue([256, Left+Width+8]);
t:=Top+Height+8;
end;
MaskEdit:=TMaskEdit.Create(Form);
with MaskEdit do
begin
Parent:=Form;
EditMask:=MEditMask;
PasswordChar:=MPasswordChar;
Text:=MEditText;
Left:=8;
Top:=t;
Width:=Form.ClientWidth-16;
t:=Top+Height+8;
end;
with TButton.Create(Form) do
begin
Parent:=Form;
Default:=true;
ModalResult:=mrOk;
Caption:='OK';
Left:=Form.ClientWidth div 2-Width-4;
Top:=t;
end;
with TButton.Create(Form) do
begin
Parent:=Form;
ModalResult:=mrCancel;
Caption:='Отмена';
Left:=Form.ClientWidth div 2+4;
Top:=t;
t:=t+Height+8;
end;
Form.ClientHeight:=t;
Result:=Form.ShowModal=mrOk;
if Result then
Value:=MaskEdit.Text else
Value:='';
FreeAndNil(Form);
end;
где:
Caption – заголовок диалогового окна;
SMS – текст сообщения;
MEditText – значение по умолчанию;
MEditMask – маска для ввода данных;
MPasswordChar – символ, замещающий фактические символы, вводимые
в поле ввода, при значении #0 символы не
заменяются, а при использовании для ввода паролей обычно пишут '*';
Value – возвращает содержимое текстовой строки.
Например, на пустую форму добавим компонент
Memo1: TMemo и кнопку Button1: TButton, прописав в ней
следующее событие:
procedure TForm1.Button1Click(Sender: TObject);
var Value: string;
begin
Memo1.Clear;
if FormInput('Пароль', 'Введите Ваше имя:', 'Евгений', '', #0, Value) then
Memo1.Lines.Add(Value) else
Memo1.Lines.Add('Пользователь отказался вводить свое имя!');
if FormInput('Пароль', 'Введите дату рождения:', '', '!99.99.9999;1;_', #0, Value) then
Memo1.Lines.Add(Value) else
Memo1.Lines.Add('Пользователь отказался вводить дату рождения!');
if FormInput('Пароль', 'Введите пароль:', '', '', '!', Value) then // можно вместо '!' написать привычное '*'
Memo1.Lines.Add(Value) else
Memo1.Lines.Add('Пользователь отказался вводить пароль!');
end;
При нажатии на кнопку появятся друг за другом диалоговые окна, где требуется в каждом
из них ввести свой текст. После обработки каждого окна в Memo1 будут
отображаться 3 строки.
|