Стандартные функции

1. Перевод всех букв строки в нижний регистр

Функция LowerCase преобразует строку S в нижний регистр, т.е. символы верхнего регистра изменяются в строку со строчными буквами.

function LowerCase(const S: string): string;

где:

• S – исходная строка.

Например,

• LowerCase('WINdows 7 ДОМАшняя: Ё-моё!') выведет 'windows 7 ДОМАшняя: Ё-моё!'.

Примечание. Как показывает пример, не все буквы преобразовались в нижний регистр: перевелись буквы английского алфавита, а русские нет. Для преобразования русских букв в нижний регистр необходима функция AnsiLowerCase.

function AnsiLowerCase(const S: string): string;

где:

• S – исходная строка.

Например,

• AnsiLowerCase('WINdows 7 ДОМАшняя: Ё-моё!') выведет 'windows 7 домашняя: ё-моё!'.

2. Перевод всех букв строки в верхний регистр

Функция UpperCase преобразует строку S в верхний регистр, т.е. символы нижнего регистра изменяются в строку с прописными буквами.

function UpperCase(const S: string): string;

где:

• S – исходная строка.

Например,

• UpperCase('WINdows 7 ДОМАшняя: Ё-моё!') выведет 'WINDOWS 7 ДОМАшняя: Ё-моё!'.

Примечание. Аналогичная ситуация с русскими буквами: функция AnsiUpperCase в помощь!

function AnsiUpperCase(const S: string): string;

где:

• S – исходная строка.

Например,

• AnsiUpperCase('WINdows 7 ДОМАшняя: Ё-моё!') выведет 'WINDOWS 7 ДОМАШНЯЯ: Ё-МОЁ!'.

В качестве дополнения рассморим функцию UpCase, которая преобразовывает однобуквенный символ к верхнему регистру. Русские буквы не поддерживает!

function UpCase(Ch: Char): Char;

где:

• Ch – исходная английская буква.

Например,

• UpCase('w') выведет 'W'.

Авторские функции

3. Проверка регистра буквы

Функция RegistrCharLower проверяет нижний регистр буквы.

function RegistrCharLower(c: char): boolean;
begin
   Result:=(c>='a') and (c<='z') or (c>='а') and (c<='я') or (c='ё');
end;

где:

• c – символ.

Например,

• RegistrCharLower('ы') выведет true;
• RegistrCharLower('Ъ') выведет false.

Функция RegistrCharUpper проверяет верхний регистр буквы.

function RegistrCharUpper(c: char): boolean;
begin
   Result:=(c>='A') and (c<='Z') or (c>='А') and (c<='Я') or (c='Ё');
end;

где:

• c – символ.

Например,

• RegistrCharUpper('Й') выведет true;
• RegistrCharUpper('д') выведет false.

4. Проверка строчных и прописных букв в строке

Функция RegistrStringLower определяет, есть ли в строке буквы нижнего регистра.

function RegistrStringLower(s: string): boolean;
var i: integer;
begin
   Result:=false;
   for i:=1 to Length(s) do
      if RegistrCharLower(s[i]) then
      begin
         Result:=true;
         Exit;
      end;
end;

где:

• s – строка.

Например,

• RegistrStringLower('Паспорт') выведет true;
• RegistrStringLower('ИНН') выведет false.

Функция RegistrStringUpper определяет, есть ли в строке буквы верхнего регистра.

function RegistrStringUpper(s: string): boolean;
var i: integer;
begin
   Result:=false;
   for i:=1 to Length(s) do
      if RegistrCharUpper(s[i]) then
      begin
         Result:=true;
         Exit;
      end;
end;

где:

• s – строка.

Например,

• RegistrStringUpper('Программа') выведет true;
• RegistrStringUpper('паскаль') выведет false.