1. Минимальное число в массиве

В модуле Math функция MinValue возвращает наименьшее значение числового массива Data.

function MinValue(const Data: array of Double): Double;

где:

• Data – массив, состоящий из дробных десятичных чисел.

Также в модуле Math имеется функция MinIntValue, которая возвращает наименьшее значение целочисленного массива Data.

function MinIntValue(const Data: array of Integer): Integer;

где:

• Data – массив, состоящий из целых чисел.

Чтобы понять принцип работы вышеуказанных функций, напишем свою функцию MinArray.

function MinArray(p: array of integer): integer;
var i: integer;
begin
   Result:=p[Low(p)];
   for i:=Low(p)+1 to High(p) do
      if Result>p[i] then
         Result:=p[i];
end;

где:

• p – массив из целых чисел.

Например,

• MinArray([6, 3, 8, 7, 4, 5]) выведет '3'.

Примечание. В функции MinArray допускается использовать не только целочисленные числа, но и вещественные (дробные десятичные). В этом случае integer заменяют на real:

function MinArray(p: array of real): real;

Текст программного кода остается неизменным.

2. Максимальное число в массиве

В модуле Math функция MaxValue возвращает наибольшее значение числового массива Data.

function MaxValue(const Data: array of Double): Double;

где:

• Data – массив, состоящий из дробных десятичных чисел.

Также в модуле Math имеется функция MaxIntValue, которая возвращает наибольшее значение целочисленного массива Data.

function MaxIntValue(const Data: array of Integer): Integer;

где:

• Data – массив, состоящий из целых чисел.

Чтобы понять принцип работы вышеуказанных функций, напишем свою функцию MaxArray.

function MaxArray(p: array of integer): integer;
var i: integer;
begin
   Result:=p[Low(p)];
   for i:=Low(p)+1 to High(p) do
      if Result<p[i] then
         Result:=p[i];
end;

где:

• p – массив из целых чисел.

Например,

• MaxArray([6, 3, 8, 7, 4, 5]) выведет '8'.

Примечание. В функции MaxArray допускается использовать не только целочисленные числа, но и вещественные (дробные десятичные). В этом случае integer заменяют на real:

function MaxArray(p: array of real): real;

Текст программного кода остается неизменным.

3. Среднее значение массива

Функция Mean из модуля Math используется для вычисления среднего значения (арифметическое среднее) набора числовых значений: она суммирует все значения в списке и делит сумму на количество элементов.

function Mean(const Data: array of Double): Extended;

где:

• Data – массив, состоящий из чисел.

Рассмотрим программный код написанной нами функции MeanArray.

function MeanArray(p: array of real): real;
var i: integer;
begin
   Result:=0;
   for i:=Low(p) to High(p) do
      Result:=Result+p[i];
   Result:=Result/(High(p)-Low(p)+1);
end;

где:

• p – массив из чисел.

Например,

• MeanArray([5, 2, 6, 7, 1]) выведет '4,2'.