Начало...

Рассмотрим работу функции для вещественных (дробных) чисел.

function Random3: extended;
const two2neg32 = 1/$100000000; // 2^-32
var z: int64;
begin
   RandSeed:=RandSeed*$8088405 + 1;
   z:=RandSeed;
   If z<0 then
      z:=z+$100000000;
   Result:=z*two2neg32;
end;

Примечание 1. Допускается перегружать процедуры и функции с одинаковыми именами, дописав слово overload:

function Random1: extended; overload;

Примечание 2. Константа two2neg32 равна 0,00000000023283064365386962890625 (2 в степени -32).

Рассмотрим пример образования последовательности вещественных чисел в диапазоне от 0 до 1. Процедуру Randomize вызывать не будем (RandSeed = 0). Последовательность чисел будем вызывать с помощью функций Random3 и Random (для проверки).

procedure TForm1.Button2Click(Sender: TObject);
const rs = 0;
var i: integer;
    a: real;
begin
   Memo1.Clear;
   RandSeed:=rs;
   For i:=1 to 30 do
   begin
      a:=Random;
      Memo1.Lines.Add(Format('%d число = %g, RandSeed = %d',[i,a,RandSeed]));
   end;
   Memo2.Clear;
   RandSeed:=rs;
   For i:=1 to 30 do
   begin
      a:=Random3;
      Memo2.Lines.Add(Format('%d число = %g, RandSeed = %d',[i,a,RandSeed]));
   end;
end;

Тексты в Memo1 и Memo2 будут выглядеть одинаково:

Таким образом, при неоднократном вызове Random функция выдаст последовательность чисел: 2,3283064365387E-10, 0,0313799395225942, 0,861048467224464, 0,202580965124071, 0,272921267198399, 0,671654418576509, 0,318691271124408, 0,161795465275645, 0,372238358715549, 0,425673767458647, 0,0820121595170349, 0,474794064648449, 0,0705693301279098, 0,84085443476215, 0,0597242347430438, 0,293296571820974 и т.д.

Рассмотрим подробно образование случайных чисел. Вычисления проведем в таблице.

Далее аналогичным образом рассчитываются следующие числа.

Рассмотрим следующую функцию, написанную на ассемблере.

function Random4: extended;
const two2neg32: double = 1/$100000000; // 2^-32
asm
   IMUL EDX,RandSeed,$8088405
   INC EDX
   MOV RandSeed,EDX
   FLD QWORD PTR two2neg32
   PUSH $0
   PUSH EDX
   FILD QWORD PTR [ESP]
   ADD ESP,$4
   POP EDX
   FMULP
   FSTP TBYTE PTR Result
end;

Комментарии:

IMUL EDX,RandSeed,$8088405 - умножает RandSeed на $8088405 и записывает в регистр EDX;

INC EDX - увеличивает значение регистра EDX на единицу;

MOV RandSeed,EDX - присваивает переменной RandSeed значение регистра EDX;

FLD QWORD PTR two2neg32 - загружает 64-разрядное вещественное число two2neg32 в ST(0) (вершину стека сопроцессора);

PUSH $0 - размещает значение "0" в стеке, т.е. помещает значение в ячейку памяти, на которую указывает регистр ESP, после этого значение регистра ESP уменьшается на 4;

PUSH EDX - размещает значение регистра EDX в стеке;

FILD QWORD PTR [ESP] - загружает 64-разрядное целое число в регистр ST(0) (вершину стека сопроцессора) из области памяти по адресу ESP, при загрузке какого-либо значения в стек сопроцессора все значения стека сдвигаются, т.е. значение регистра ST(0) загрузит в ST(1), а наше новое значение загружается в ST(0);

ADD ESP,$4 - увеличивает значение регистра ESP на 4;

POP EDX - извлекает значение из стека, т.е. извлекает значение из ячейки памяти, на которую указывает регистр ESP, и сохраняет в регистре EDX, после этого увеличивает значение регистра ESP на 4;

FMULP - умножение значений регистра ST(0) сопроцессора на ST(1) и выталкивание из стека (значение в ST(1) будет Empty /нет данных/), результат записывается в ST(0);

FSTP TBYTE PTR Result - записывает 80-разрядное вещественное число из регистра ST(0) в переменную Result, при этом происходит выталкивание вершины из стека сопроцессора (ST(0) = Empty).

Рассмотрим пример образования последовательности вещественных чисел в диапазоне от 0 до 1. Процедуру Randomize вызывать не будем (RandSeed = 0). Последовательность чисел будем вызывать с помощью функций Random4 и Random (для проверки).

В процедуре TForm1.Button2Click в коде заменим функцию Random3(r) на Random4(r).

Тексты в Memo1 и Memo2 будут выглядеть одинаково:

Таким образом, при неоднократном вызове Random функция выдаст последовательность чисел: 2,3283064365387E-10, 0,0313799395225942, 0,861048467224464, 0,202580965124071, 0,272921267198399, 0,671654418576509, 0,318691271124408, 0,161795465275645, 0,372238358715549, 0,425673767458647, 0,0820121595170349, 0,474794064648449, 0,0705693301279098, 0,84085443476215, 0,0597242347430438, 0,293296571820974 и т.д.

Рассмотрим подробно образование случайных чисел. Вычисления проведем в таблице.

Далее аналогичным образом рассчитываются следующие числа.

Примечание 1. Здесь дополнительно используется значение регистра ESP - это указатель вершины стека. В регистре ESP хранится адрес последней добавленной записи.

Примечание 2. Строки "ADD ESP,$4" и "POP EDX" можно заменить одной строкой "ADD ESP,$8". Это означает, что команда ADD увеличит значение регистра ESP сразу на 8, а в регистре EDX останется старое значение.